000100 IDENTIFICATION DIVISION.
000200 PROGRAM-ID.           PPOPN171.
000300*AUTHOR.             DDS TEAM.
000400*                        CMS.
000500*REMARKS.
000600*    EFFECTIVE JAN 1,2006  CONVERTED SOFTWARE TO CICS FORMAT
000700*          - OPENS PROV,MSAX AND CBSA FILES
000800*          - FINDS PROV RECORD
000900*          - LOADS THE MSAX AND CBSA TABLES
001000*          - CALLS THE DRIVER MODULE
001100 DATE-COMPILED.
001200****************************************************************
001300*   PRICER CICS VERSION                                        *
001400****************************************************************
001500* PPOPN074 VERSION FOR PRICING A NEW TECHNICAL ADD ON        ***
001600*                                                            ***
001700****************************************************************
001800****************************************************************
001900* PPOPN171 VERSION FOR FY 2017 PRICER                        ***
002000*                                                            ***
002100****************************************************************
002200 ENVIRONMENT DIVISION.
002300 CONFIGURATION SECTION.
002400 SOURCE-COMPUTER.            IBM-370.
002500 OBJECT-COMPUTER.            IBM-370.
002600 INPUT-OUTPUT  SECTION.
002700 FILE-CONTROL.
002800
002900     SELECT PROV-FILE ASSIGN      TO  UT-S-PPSPROV
003000            FILE STATUS IS PROV-STAT.
003100     SELECT MSAX-FILE ASSIGN      TO  UT-S-PPSMSAX
003200            FILE STATUS IS MSAX-STAT.
003300     SELECT F-CBSA-FILE ASSIGN    TO  UT-S-PPSCBSA
003400            FILE STATUS IS CBSA-STAT.
003500
003600 DATA DIVISION.
003700 FILE SECTION.
003800
003900 FD  PROV-FILE
004000     RECORDING MODE IS F
004100     LABEL RECORDS ARE STANDARD
004200     BLOCK CONTAINS 0 RECORDS.
004300 01  PROV-REC.
004400     05  PROV-PART1                 PIC X(80).
004500     05  PROV-PART2                 PIC X(80).
004600     05  PROV-PART3                 PIC X(150).
004700
004800 FD  MSAX-FILE
004900     RECORDING MODE IS F
005000     LABEL RECORDS ARE STANDARD
005100     BLOCK CONTAINS 0 RECORDS.
005200***************************************************************
005300*    THIS RECORD IS SUPPLIED BY CMS  AND CONTAINS             *
005400*    THE WAGE INDEX FOR THE STATES (RURAL) AND MSA'S (URBAN). *
005500***************************************************************
005600 01  MSAX-REC.
005700     05  X-MSA-X.
005800         10  M-BLANK                PIC X(02).
005900         10  M-STATE                PIC 9(02).
006000     05  X-MSA REDEFINES X-MSA-X    PIC 9(04).
006100     05  X-SIZE                     PIC X(01).
006200     05  XE-DATE.
006300         10  XE-CC                  PIC 9(02).
006400         10  XE-YY                  PIC 9(02).
006500         10  XE-MM                  PIC 9(02).
006600         10  XE-DD                  PIC 9(02).
006700     05  FILLER                     PIC X(01).
006800     05  X-WAGE-INDX1               PIC S9(02)V9(04).
006900     05  FILLER                     PIC X(01).
007000     05  X-WAGE-INDX2               PIC S9(02)V9(04).
007100     05  FILLER                     PIC X(01).
007200     05  X-STATE-MSA-NAME           PIC X(51).
007300     05  FILLER                     PIC X(01).
007400
007500 FD  F-CBSA-FILE
007600     RECORDING MODE IS F
007700     LABEL RECORDS ARE STANDARD
007800     BLOCK CONTAINS 0 RECORDS.
007900***************************************************************
008000*    THIS RECORD IS SUPPLIED BY CMS  AND CONTAINS             *
008100*    THE WAGE INDEX FOR THE STATES (RURAL) AND MSA'S (URBAN). *
008200***************************************************************
008300 01  F-CBSA-REC.
008400     05  F-CBSA.
008500         10  F-CBSA-BLANK                PIC X(03).
008600         10  F-CBSA-STATE                PIC 9(02).
008700     05  F-CBSA9  REDEFINES F-CBSA       PIC 9(05).
008800     05  F-CBSA-SIZE             PIC X(01).
008900     05  F-CBSA-EFF-DATE.
009000         10  F-CBSA-CC           PIC 9(02).
009100         10  F-CBSA-YY           PIC 9(02).
009200         10  F-CBSA-MM           PIC 9(02).
009300         10  F-CBSA-DD           PIC 9(02).
009400     05  FILLER                  PIC X(01).
009500     05  F-CBSA-WAGE-INDX1       PIC S9(02)V9(04).
009600     05  FILLER                  PIC X(01).
009700     05  F-CBSA-WAGE-INDX2       PIC S9(02)V9(04).
009800     05  FILLER                  PIC X(01).
009900     05  F-CBSA-STATE-NAME       PIC X(50).
010000     05  FILLER                  PIC X(01).
010100
010200 WORKING-STORAGE SECTION.
010300 77  W-STORAGE-REF                  PIC X(48)  VALUE
010400     'I/O PRICER FILES- W O R K I N G   S T O R A G E'.
010500
010600 01  PPDRV171                       PIC X(08) VALUE 'PPDRV171'.
010700 01  TABLES-LOADED-SW               PIC 9(01)  VALUE 0.
010800 01  EOF-SW                         PIC 9(01)  VALUE 0.
010900
011000 01  PROV-STAT.
011100     02  PROV-STAT1     PIC X.
011200     02  PROV-STAT2     PIC X.
011300
011400 01  MSAX-STAT.
011500     02  MSAX-STAT1     PIC X.
011600     02  MSAX-STAT2     PIC X.
011700
011800 01  CBSA-STAT.
011900     02  CBSA-STAT1     PIC X.
012000     02  CBSA-STAT2     PIC X.
012100
012200 01  MSAX-WI-TABLE.
012300     05  M-MSAX-DATA                OCCURS 9000
012400                                    INDEXED BY MU1 MU2 MU3.
012500         10  M-MSAX-MSA             PIC X(4).
012600         10  M-MSAX-SIZE            PIC X(01).
012700         10  M-MSAX-EFF-DATE        PIC X(08).
012800         10  M-MSAX-WAGE-INDX1      PIC S9(02)V9(04).
012900         10  M-MSAX-WAGE-INDX2      PIC S9(02)V9(04).
013000
013100*****************************************************************
013200**************YEARCHANGE 2015.2 **********************      *****
013300
013400 01  CBSA-WI-TABLE.
013500     05  T-CBSA-DATA                  OCCURS 7000
013600                                    INDEXED BY MA1 MA2 MA3.
013700         10  T-CBSA                   PIC X(5).
013800         10  T-CBSA-SIZE              PIC X(01).
013900         10  T-CBSA-EFF-DATE          PIC X(08).
014000         10  T-CBSA-WAGE-INDX1        PIC S9(02)V9(04).
014100         10  T-CBSA-WAGE-INDX2        PIC S9(02)V9(04).
014200
014300**************YEARCHANGE 2015.2 **********************      *****
014400***************************************************************
014500*    THE PROVIDER SPECIFIC INFORMATION TABLE IS INITIALLY     *
014600*    SET TO OCCUR 4000 TIMES. THIS NUMBER SHOULD BY ADJUSTED  *
014700*    BY THE USER TO REFLECT THE NUMBER OF PROVIDER RECORDS    *
014800*    PLUS EXPANSION. EACH ENTRY COSTS 240 BYTES OF MEMORY.    *
014900*    THIS FILE MUST BE IN PROVIDER NUMBER, EFFECTIVE-DATE     *
015000*    SEQUENCE.                                                *
015100***************************************************************
015200 01  PROV-TABLE.
015300     05  PROV-ENTRIES               OCCURS 4000
015400                                    ASCENDING KEY IS PROV-NO
015500                                    INDEXED BY PX1 PX2 PX3.
015600         10  PROV-DATA1.
015700             15  PROV-NPI10.
015800                 20  PROV-NPI8       PIC X(08).
015900                 20  PROV-NPI-FILLER PIC X(02).
016000             15  PROV-NO             PIC X(06).
016100             15  PROV-EFF-DATE       PIC X(08).
016200             15  FILLER              PIC X(56).
016300 01  PROV-DATA-2.
016400     05  PROV-ENTRIES2               OCCURS 4000
016500                                     INDEXED BY PD2.
016600         10  PROV-DATA2              PIC X(80).
016700 01  PROV-DATA-3.
016800     05  PROV-ENTRIES3               OCCURS 4000
016900                                     INDEXED BY PD3.
017000         10  PROV-DATA3              PIC X(150).
017100
017200***************************************************************
017300*      THIS IS THE WAGE-INDEX RECORD THAT WILL BE PASSED TO   *
017400*      THE PPCAL001 PROGRAM THRU PPCAL046 FOR PROCESSING
017500***************************************************************
017600 01  WAGE-NEW-INDEX-RECORD.
017700     05  W-NEW-MSA               PIC 9(4).
017800     05  W-NEW-SIZE              PIC X(01).
017900         88  NEW-LARGE-URBAN       VALUE 'L'.
018000         88  NEW-OTHER-URBAN       VALUE 'O'.
018100         88  NEW-ALL-RURAL         VALUE 'R'.
018200     05  W-NEW-EFF-DATE.
018300          10  W-NEW-EFF-DATE-CC   PIC 9(2).
018400          10  W-NEW-EFF-DATE-YMD.
018500              15  W-NEW-EFF-DATE-YY   PIC 9(2).
018600              15  W-NEW-EFF-DATE-MM   PIC 9(2).
018700              15  W-NEW-EFF-DATE-DD   PIC 9(2).
018800     05  FILLER              PIC X.
018900     05  W-NEW-INDEX-RECORD      PIC S9(02)V9(04).
019000     05  W-NEW-PR-INDEX-RECORD   PIC S9(02)V9(04).
019100
019200***************************************************************
019300*      THIS IS THE WAGE-INDEX RECORD THAT WILL BE PASSED TO   *
019400*      THE PPCAL051 PROGRAM AND AFTER FOR PROCESSING
019500***************************************************************
019600 01  WAGE-NEW-CBSA-INDEX-RECORD.
019700     05  W-NEW-CBSA               PIC 9(5).
019800     05  W-NEW-CBSA-X  REDEFINES W-NEW-CBSA     PIC X(05).
019900     05  W-NEW-CBSA-SIZE              PIC X(01).
020000         88  NEW-CBSA-LARGE-URBAN       VALUE 'L'.
020100         88  NEW-CBSA-OTHER-URBAN       VALUE 'O'.
020200         88  NEW-CBSA-ALL-RURAL         VALUE 'R'.
020300     05  W-NEW-CBSA-EFF-DATE.
020400          10  W-NEW-CBSA-EFF-DATE-CC   PIC 9(2).
020500          10  W-NEW-CBSA-EFF-DATE-YMD.
020600              15  W-NEW-CBSA-EFF-DATE-YY   PIC 9(2).
020700              15  W-NEW-CBSA-EFF-DATE-MM   PIC 9(2).
020800              15  W-NEW-CBSA-EFF-DATE-DD   PIC 9(2).
020900     05  FILLER                      PIC X.
021000     05  W-NEW-CBSA-WI               PIC S9(02)V9(04).
021100     05  W-NEW-CBSA-PR-WI            PIC S9(02)V9(04).
021200
021300**************************************************************
021400*      THIS IS THE PROV-RECORD THAT WILL BE PASSED TO        *
021500*      THE PPDRV___ PROGRAM FOR PROCESSING                   *
021600**************************************************************
021700 01  PROV-NEW-HOLD.
021800     02  PROV-NEWREC-HOLD1.
021900         05  P-NEW-NPI10.
022000             10  P-NEW-NPI8             PIC X(08).
022100             10  P-NEW-NPI-FILLER       PIC X(02).
022200         05  P-NEW-PROVIDER-NO.
022300             10  P-NEW-STATE            PIC 9(02).
022400             10  FILLER                 PIC X(04).
022500         05  P-NEW-DATE-DATA.
022600             10  P-NEW-EFF-DATE.
022700                 15  P-NEW-EFF-DT-CC    PIC 9(02).
022800                 15  P-NEW-EFF-DT-YY    PIC 9(02).
022900                 15  P-NEW-EFF-DT-MM    PIC 9(02).
023000                 15  P-NEW-EFF-DT-DD    PIC 9(02).
023100             10  P-NEW-FY-BEGIN-DATE.
023200                 15  P-NEW-FY-BEG-DT-CC PIC 9(02).
023300                 15  P-NEW-FY-BEG-DT-YY PIC 9(02).
023400                 15  P-NEW-FY-BEG-DT-MM PIC 9(02).
023500                 15  P-NEW-FY-BEG-DT-DD PIC 9(02).
023600             10  P-NEW-REPORT-DATE.
023700                 15  P-NEW-REPORT-DT-CC PIC 9(02).
023800                 15  P-NEW-REPORT-DT-YY PIC 9(02).
023900                 15  P-NEW-REPORT-DT-MM PIC 9(02).
024000                 15  P-NEW-REPORT-DT-DD PIC 9(02).
024100             10  P-NEW-TERMINATION-DATE.
024200                 15  P-NEW-TERM-DT-CC   PIC 9(02).
024300                 15  P-NEW-TERM-DT-YY   PIC 9(02).
024400                 15  P-NEW-TERM-DT-MM   PIC 9(02).
024500                 15  P-NEW-TERM-DT-DD   PIC 9(02).
024600         05  P-NEW-WAIVER-CODE          PIC X(01).
024700             88  P-NEW-WAIVER-STATE       VALUE 'Y'.
024800         05  P-NEW-INTER-NO             PIC 9(05).
024900         05  P-NEW-PROVIDER-TYPE        PIC X(02).
025000             88  P-N-SOLE-COMMUNITY-PROV    VALUE '01' '11'.
025100             88  P-N-REFERRAL-CENTER        VALUE '07' '11'
025200                                                  '15' '17'
025300                                                  '22'.
025400             88  P-N-INDIAN-HEALTH-SERVICE  VALUE '08'.
025500             88  P-N-REDESIGNATED-RURAL-YR1 VALUE '09'.
025600             88  P-N-REDESIGNATED-RURAL-YR2 VALUE '10'.
025700             88  P-N-SOLE-COM-REF-CENT      VALUE '11'.
025800             88  P-N-MDH-REBASED-FY90       VALUE '14' '15'.
025900             88  P-N-MDH-RRC-REBASED-FY90   VALUE '15'.
026000             88  P-N-SCH-REBASED-FY90       VALUE '16' '17'.
026100             88  P-N-SCH-RRC-REBASED-FY90   VALUE '17'.
026200             88  P-N-MEDICAL-ASSIST-FACIL   VALUE '18'.
026300             88  P-N-EACH                   VALUE '21' '22'.
026400             88  P-N-EACH-REFERRAL-CENTER   VALUE '22'.
026500             88  P-N-NHCMQ-II-SNF           VALUE '32'.
026600             88  P-N-NHCMQ-III-SNF          VALUE '33'.
026700         05  P-NEW-CURRENT-CENSUS-DIV   PIC 9(01).
026800             88  P-N-NEW-ENGLAND            VALUE  1.
026900             88  P-N-MIDDLE-ATLANTIC        VALUE  2.
027000             88  P-N-SOUTH-ATLANTIC         VALUE  3.
027100             88  P-N-EAST-NORTH-CENTRAL     VALUE  4.
027200             88  P-N-EAST-SOUTH-CENTRAL     VALUE  5.
027300             88  P-N-WEST-NORTH-CENTRAL     VALUE  6.
027400             88  P-N-WEST-SOUTH-CENTRAL     VALUE  7.
027500             88  P-N-MOUNTAIN               VALUE  8.
027600             88  P-N-PACIFIC                VALUE  9.
027700         05  P-NEW-CURRENT-DIV   REDEFINES
027800                    P-NEW-CURRENT-CENSUS-DIV   PIC 9(01).
027900             88  P-N-VALID-CENSUS-DIV    VALUE 1 THRU 9.
028000         05  P-NEW-MSA-DATA.
028100             10  P-NEW-CHG-CODE-INDEX       PIC X.
028200             10  P-NEW-GEO-LOC-MSAX         PIC X(04) JUST RIGHT.
028300             10  P-NEW-GEO-LOC-MSA9   REDEFINES
028400                             P-NEW-GEO-LOC-MSAX  PIC 9(04).
028500             10  P-NEW-GEO-LOC-MSA-AST REDEFINES
028600                             P-NEW-GEO-LOC-MSA9.
028700                 15  P-NEW-GEO-MSA-1ST    PIC X.
028800                 15  P-NEW-GEO-MSA-2ND    PIC X.
028900                 15  P-NEW-GEO-MSA-3RD    PIC X.
029000                 15  P-NEW-GEO-MSA-4TH    PIC X.
029100             10  P-NEW-WAGE-INDEX-LOC-MSA   PIC X(04) JUST RIGHT.
029200             10  P-NEW-STAND-AMT-LOC-MSA    PIC X(04) JUST RIGHT.
029300             10  P-NEW-STAND-AMT-LOC-MSA9
029400       REDEFINES P-NEW-STAND-AMT-LOC-MSA.
029500                 15  P-NEW-RURAL-1ST.
029600                     20  P-NEW-STAND-RURAL  PIC XX.
029700                         88  P-NEW-STD-RURAL-CHECK VALUE '  '.
029800                 15  P-NEW-RURAL-2ND        PIC XX.
029900         05  P-NEW-SOL-COM-DEP-HOSP-YR PIC XX.
030000                 88  P-NEW-SCH-YRBLANK    VALUE   '  '.
030100                 88  P-NEW-SCH-YR82       VALUE   '82'.
030200                 88  P-NEW-SCH-YR87       VALUE   '87'.
030300         05  P-NEW-LUGAR                    PIC X.
030400         05  P-NEW-TEMP-RELIEF-IND          PIC X.
030500             88  P-NEW-LOW-VOL25PCT     VALUE 'Y'.
030600***          Y = LOW VOLUME PERCENTAGE  25 % ADD ON
030700         05  P-NEW-FED-PPS-BLEND-IND        PIC X.
030800         05  P-NEW-STATE-CODE               PIC 9(02).
030900         05  P-NEW-STATE-CODE-X REDEFINES
031000             P-NEW-STATE-CODE               PIC X(02).
031100         05  FILLER                         PIC X(03).
031200     02  PROV-NEWREC-HOLD2.
031300         05  P-NEW-VARIABLES.
031400             10  P-NEW-CMI-ADJ-CPD       PIC  9(05)V9(02).
031500             10  P-NEW-COLA              PIC  9(01)V9(03).
031600             10  P-NEW-INTERN-RATIO      PIC  9(01)V9(04).
031700             10  P-NEW-BED-SIZE          PIC  9(05).
031800             10  P-NEW-CCR               PIC  9(01)V9(03).
031900             10  P-NEW-CMI               PIC  9(01)V9(04).
032000             10  P-NEW-SSI-RATIO         PIC  V9(04).
032100             10  P-NEW-MEDICAID-RATIO    PIC  V9(04).
032200             10  P-NEW-PPS-BLEND-YR-IND  PIC  X(01).
032300             10  P-NEW-PRUP-UPDTE-FACTOR PIC  9(01)V9(05).
032400             10  P-NEW-DSH-PERCENT       PIC  V9(04).
032500             10  P-NEW-FYE-DATE.
032600                 15  P-NEW-FYE-CC        PIC 99.
032700                 15  P-NEW-FYE-YY        PIC 99.
032800                 15  P-NEW-FYE-MM        PIC 99.
032900                 15  P-NEW-FYE-DD        PIC 99.
033000         05  P-NEW-CBSA-DATA.
033100             10  P-NEW-CBSA-SPEC-PAY-IND    PIC X.
033200                 88  P-NEW-CBSA-WI-GEO        VALUE 'N'.
033300                 88  P-NEW-CBSA-WI-RECLASS    VALUE 'Y'.
033400                 88  P-NEW-CBSA-WI-SPECIAL    VALUE '1' '2'.
033500***                  1 = ANYTHING OR HOLD HARMLESS WITH SPEC WI
033600***                  2 = RECLASS WITH SPEC WI
033700             10  P-NEW-CBSA-HOSP-QUAL-IND  PIC X.
033800                 88  P-NEW-CBSA-HOSP-QUAL-MET   VALUE '1'.
033900                 88  P-NEW-CBSA-HOSP-QUAL-25PER VALUE '2'.
034000                 88  P-NEW-CBSA-HOSP-QUAL-BOTH  VALUE '3'.
034100             10  P-NEW-CBSA-GEO-LOC        PIC X(05) JUST RIGHT.
034200             10  P-NEW-CBSA-GEO-LOC9  REDEFINES
034300                             P-NEW-CBSA-GEO-LOC  PIC 9(05).
034400             10  P-NEW-CBSA-GEO-LOC-AST REDEFINES
034500                             P-NEW-CBSA-GEO-LOC9.
034600                 15  P-NEW-CBSA-GEO-1ST    PIC X.
034700                 15  P-NEW-CBSA-GEO-2ND    PIC X.
034800                 15  P-NEW-CBSA-GEO-3RD    PIC X.
034900                 15  P-NEW-CBSA-GEO-4TH    PIC X.
035000                 15  P-NEW-CBSA-GEO-5TH    PIC X.
035100             10  P-NEW-CBSA-RECLASS-LOC    PIC X(05) JUST RIGHT.
035200             10  P-NEW-CBSA-STAND-AMT-LOC  PIC X(05) JUST RIGHT.
035300             10  P-NEW-CBSA-STAND-AMT-LOC-MSA9
035400       REDEFINES P-NEW-CBSA-STAND-AMT-LOC.
035500               15  P-NEW-CBSA-RURAL-1ST.
035600                   20  P-NEW-CBSA-STAND-RURAL  PIC XXX.
035700                      88  P-NEW-CBSA-STD-RURAL-CHECK VALUE '   '.
035800               15  P-NEW-CBSA-RURAL-2ND    PIC XX.
035900             10  P-NEW-CBSA-SPEC-WI          PIC 9(02)V9(04).
036000             10  P-NEW-CBSA-SPEC-WI-N  REDEFINES
036100                 P-NEW-CBSA-SPEC-WI          PIC 9(06).
036200     02  PROV-NEWREC-HOLD3.
036300         05  P-NEW-PASS-AMT-DATA.
036400             10  P-NEW-PASS-AMT-CAPITAL    PIC 9(04)V99.
036500             10  P-NEW-PASS-AMT-DIR-MED-ED PIC 9(04)V99.
036600             10  P-NEW-PASS-AMT-ORGAN-ACQ  PIC 9(04)V99.
036700             10  P-NEW-PASS-AMT-PLUS-MISC  PIC 9(04)V99.
036800         05  P-NEW-CAPI-DATA.
036900             15  P-NEW-CAPI-PPS-PAY-CODE   PIC X.
037000             15  P-NEW-CAPI-HOSP-SPEC-RATE PIC 9(04)V99.
037100             15  P-NEW-CAPI-OLD-HARM-RATE  PIC 9(04)V99.
037200             15  P-NEW-CAPI-NEW-HARM-RATIO PIC 9(01)V9999.
037300             15  P-NEW-CAPI-CSTCHG-RATIO   PIC 9V999.
037400             15  P-NEW-CAPI-NEW-HOSP       PIC X.
037500             15  P-NEW-CAPI-IME            PIC 9V9999.
037600             15  P-NEW-CAPI-EXCEPTIONS     PIC 9(04)V99.
037700         05  P-HVBP-HRR-DATA.
037800             15  P-NEW-VAL-BASED-PURCH-PARTIPNT PIC X.
037900             15  P-NEW-VAL-BASED-PURCH-ADJUST   PIC 9V9(11).
038000             15  P-NEW-HOSP-READMISSION-REDU    PIC X.
038100             15  P-NEW-HOSP-HRR-ADJUSTMT        PIC 9V9(4).
038200         05  P-MODEL1-BUNDLE-DATA.
038300             15  P-MODEL1-BUNDLE-DISPRCNT   PIC V999.
038400             15  P-HAC-REDUC-IND            PIC X.
038500             15  P-UNCOMP-CARE-AMOUNT       PIC 9(07)V99.
038600             15  P-EHR-REDUC-IND            PIC X.
038700             15  P-LV-ADJ-FACTOR            PIC 9V9(6).
038800         05  P-NEW-COUNTY-CODE              PIC 9(05).
038900         05  FILLER                         PIC X(47).
039000
039100***************************************************************
039200 LINKAGE SECTION.
039300
039400 01  BILL-NEW-DATA.
039500         10  B-N-NPI10.
039600            15  B-N-NPI8              PIC X(08).
039700            15  B-N-NPI-FILLER        PIC X(02).
039800         10  B-N-PROVIDER-NO          PIC X(06).
039900         10  B-N-REVIEW-CODE          PIC 9(02).
040000             88  N-VALID-REVIEW-CODE    VALUE 00 THRU 09 11.
040100             88  N-PAY-WITH-OUTLIER     VALUE 00 07.
040200             88  N-PAY-DAYS-OUTLIER     VALUE 01.
040300             88  N-PAY-COST-OUTLIER     VALUE 02.
040400             88  N-PAY-PERDIEM-DAYS     VALUE 03.
040500             88  N-PAY-AVG-STAY-ONLY    VALUE 04.
040600             88  N-PAY-XFER-WITH-COST   VALUE 05.
040700             88  N-PAY-XFER-NO-COST     VALUE 06.
040800             88  N-PAY-WITHOUT-COST     VALUE 07.
040900             88  N-PAY-DRG-480          VALUE 08.
041000             88  N-PAY-XFER-SPEC-DRG    VALUE 09 11.
041100             88  N-PAY-XFER-SPEC-DRG-NO-COST VALUE 11.
041200         10  B-N-DRG                  PIC 9(03).
041300         10  B-N-LOS                  PIC 9(03).
041400         10  B-N-COVERED-DAYS         PIC 9(03).
041500         10  B-N-LTR-DAYS             PIC 9(02).
041600         10  B-N-DISCHARGE-DATE.
041700             15  B-N-DISCHG-CC        PIC 9(02).
041800             15  B-N-DISCHG-YY        PIC 9(02).
041900             15  B-N-DISCHG-MM        PIC 9(02).
042000             15  B-N-DISCHG-DD        PIC 9(02).
042100         10  B-N-CHARGES-CLAIMED      PIC 9(07)V9(02).
042200         10  B-N-PRIN-PROC-CODE       PIC X(07).
042300         10  B-N-OTHER-PROC-CODE1     PIC X(07).
042400         10  B-N-OTHER-PROC-CODE2     PIC X(07).
042500         10  B-N-OTHER-PROC-CODE3     PIC X(07).
042600         10  B-N-OTHER-PROC-CODE4     PIC X(07).
042700         10  B-N-OTHER-PROC-CODE5     PIC X(07).
042800         10  B-N-OTHER-PROC-CODE6     PIC X(07).
042900         10  B-N-OTHER-PROC-CODE7     PIC X(07).
043000         10  B-N-OTHER-PROC-CODE8     PIC X(07).
043100         10  B-N-OTHER-PROC-CODE9     PIC X(07).
043200         10  B-N-OTHER-PROC-CODE10    PIC X(07).
043300         10  B-N-OTHER-PROC-CODE11    PIC X(07).
043400         10  B-N-OTHER-PROC-CODE12    PIC X(07).
043500         10  B-N-OTHER-PROC-CODE13    PIC X(07).
043600         10  B-N-OTHER-PROC-CODE14    PIC X(07).
043700         10  B-N-OTHER-PROC-CODE15    PIC X(07).
043800         10  B-N-OTHER-PROC-CODE16    PIC X(07).
043900         10  B-N-OTHER-PROC-CODE17    PIC X(07).
044000         10  B-N-OTHER-PROC-CODE18    PIC X(07).
044100         10  B-N-OTHER-PROC-CODE19    PIC X(07).
044200         10  B-N-OTHER-PROC-CODE20    PIC X(07).
044300         10  B-N-OTHER-PROC-CODE21    PIC X(07).
044400         10  B-N-OTHER-PROC-CODE22    PIC X(07).
044500         10  B-N-OTHER-PROC-CODE23    PIC X(07).
044600         10  B-N-OTHER-PROC-CODE24    PIC X(07).
044700         10  B-N-OTHER-DIAG-CODE1   PIC X(07).
044800         10  B-N-OTHER-DIAG-CODE2   PIC X(07).
044900         10  B-N-OTHER-DIAG-CODE3   PIC X(07).
045000         10  B-N-OTHER-DIAG-CODE4   PIC X(07).
045100         10  B-N-OTHER-DIAG-CODE5   PIC X(07).
045200         10  B-N-OTHER-DIAG-CODE6   PIC X(07).
045300         10  B-N-OTHER-DIAG-CODE7   PIC X(07).
045400         10  B-N-OTHER-DIAG-CODE8   PIC X(07).
045500         10  B-N-OTHER-DIAG-CODE9   PIC X(07).
045600         10  B-N-OTHER-DIAG-CODE10  PIC X(07).
045700         10  B-N-OTHER-DIAG-CODE11  PIC X(07).
045800         10  B-N-OTHER-DIAG-CODE12  PIC X(07).
045900         10  B-N-OTHER-DIAG-CODE13  PIC X(07).
046000         10  B-N-OTHER-DIAG-CODE14  PIC X(07).
046100         10  B-N-OTHER-DIAG-CODE15  PIC X(07).
046200         10  B-N-OTHER-DIAG-CODE16  PIC X(07).
046300         10  B-N-OTHER-DIAG-CODE17  PIC X(07).
046400         10  B-N-OTHER-DIAG-CODE18  PIC X(07).
046500         10  B-N-OTHER-DIAG-CODE19  PIC X(07).
046600         10  B-N-OTHER-DIAG-CODE20  PIC X(07).
046700         10  B-N-OTHER-DIAG-CODE21  PIC X(07).
046800         10  B-N-OTHER-DIAG-CODE22  PIC X(07).
046900         10  B-N-OTHER-DIAG-CODE23  PIC X(07).
047000         10  B-N-OTHER-DIAG-CODE24  PIC X(07).
047100         10  B-N-OTHER-DIAG-CODE25  PIC X(07).
047200         10  B-N-DEMO-DATA.
047300             15  B-N-DEMO-CODE1        PIC X(02).
047400             15  B-N-DEMO-CODE2        PIC X(02).
047500             15  B-N-DEMO-CODE3        PIC X(02).
047600             15  B-N-DEMO-CODE4        PIC X(02).
047700         10  B-N-NDC-DATA.
047800             15  B-N-NDC-NUMBER        PIC X(11).
047900         10  FILLER                     PIC X(73).
048000
048100
048200 01  PPS-DATA.
048300         10  PPS-RTC                PIC 9(02).
048400         10  PPS-WAGE-INDX          PIC 9(02)V9(04).
048500         10  PPS-OUTLIER-DAYS       PIC 9(03).
048600         10  PPS-AVG-LOS            PIC 9(02)V9(01).
048700         10  PPS-DAYS-CUTOFF        PIC 9(02)V9(01).
048800         10  PPS-OPER-IME-ADJ       PIC 9(06)V9(02).
048900         10  PPS-TOTAL-PAYMENT      PIC 9(07)V9(02).
049000         10  PPS-OPER-HSP-PART      PIC 9(06)V9(02).
049100         10  PPS-OPER-FSP-PART      PIC 9(06)V9(02).
049200         10  PPS-OPER-OUTLIER-PART  PIC 9(07)V9(02).
049300         10  PPS-REG-DAYS-USED      PIC 9(03).
049400         10  PPS-LTR-DAYS-USED      PIC 9(02).
049500         10  PPS-OPER-DSH-ADJ       PIC 9(06)V9(02).
049600         10  PPS-CALC-VERS          PIC 9(05).
049700
049800 01  PRICER-OPT-VERS-SW.
049900     02  PRICER-OPTION-SW               PIC X(01).
050000         88  ALL-TABLES-PASSED          VALUE 'A'.
050100         88  PROV-RECORD-PASSED         VALUE 'P'.
050200         88  ADDITIONAL-VARIABLES       VALUE 'M'.
050300     02  PPS-VERSIONS.
050400         10  PPDRV-VERSION              PIC X(05).
050500
050600 01  PPS-ADDITIONAL-VARIABLES.
050700     02  PPS-OPERATION-VARIABLES.
050800         05  PPS-HSP-PCT                PIC 9(01)V9(02).
050900         05  PPS-FSP-PCT                PIC 9(01)V9(02).
051000         05  PPS-NAT-PCT                PIC 9(01)V9(02).
051100         05  PPS-REG-PCT                PIC 9(01)V9(02).
051200         05  PPS-CMI-ADJ-CPD            PIC 9(05)V9(02).
051300         05  PPS-UPDATE-FACTOR          PIC 9(01)V9(05).
051400         05  PPS-DRG-WT                 PIC 9(02)V9(04).
051500         05  PPS-NAT-LABOR              PIC 9(05)V9(02).
051600         05  PPS-NAT-NLABOR             PIC 9(05)V9(02).
051700         05  PPS-REG-LABOR              PIC 9(05)V9(02).
051800         05  PPS-REG-NLABOR             PIC 9(05)V9(02).
051900         05  PPS-OPER-COLA              PIC 9(01)V9(03).
052000         05  PPS-INTERN-RATIO           PIC 9(01)V9(04).
052100         05  PPS-OPER-OUTLIER           PIC 9(07)V9(09).
052200         05  PPS-OPER-BILL-COSTS        PIC 9(07)V9(09).
052300         05  PPS-OPER-DOLLAR-THRESHOLD  PIC 9(07)V9(09).
052400         05  PPS-DSCHG-FRCTN            PIC 9(1)V9999.
052500         05  PPS-DRG-WT-FRCTN           PIC 9(2)V9999.
052600         05  PPS-CAPITAL-VARIABLES.
052700             10  PPS-CAPI-TOTAL-PAY         PIC S9(07)V9(02).
052800             10  PPS-CAPI-HSP               PIC S9(07)V9(02).
052900             10  PPS-CAPI-FSP               PIC S9(07)V9(02).
053000             10  PPS-CAPI-OUTLIER           PIC S9(07)V9(02).
053100             10  PPS-CAPI-OLD-HARM          PIC S9(07)V9(02).
053200             10  PPS-CAPI-DSH-ADJ           PIC S9(07)V9(02).
053300             10  PPS-CAPI-IME-ADJ           PIC S9(07)V9(02).
053400             10  PPS-CAPI-EXCEPTIONS        PIC S9(07)V9(02).
053500         05  PPS-CAPITAL2-VARIABLES.
053600             10  PPS-CAPI2-PAY-CODE          PIC X(1).
053700             10  PPS-CAPI2-B-FSP             PIC S9(07)V9(02).
053800             10  PPS-CAPI2-B-OUTLIER         PIC S9(07)V9(02).
053900         05  PPS-OTHER-VARIABLES.
054000             10  PPS-NON-TEMP-RELIEF-PAYMENT PIC 9(07)V9(02).
054100             10  PPS-NEW-TECH-PAY-ADD-ON     PIC 9(07)V9(02).
054200             10  PPS-ISLET-ISOL-PAY-ADD-ON   PIC 9(07)V9(02).
054300             10  PPS-LOW-VOL-PAYMENT         PIC 9(07)V9(02).
054400         10  PPS-HVBP-HRR-DATA.
054500             15  PPS-VAL-BASED-PURCH-PARTIPNT PIC X.
054600             15  PPS-VAL-BASED-PURCH-ADJUST   PIC 9V9(11).
054700             15  PPS-HOSP-READMISS-REDUCTN    PIC X.
054800             15  PPS-HOSP-HRR-ADJUSTMT        PIC 9V9(4).
054900         10  PPS-OPERATNG-DATA.
055000             15  PPS-MODEL1-BUNDLE-DISPRCNT  PIC V999.
055100             15  PPS-OPER-BASE-DRG-PAY       PIC 9(08)V99.
055200             15  PPS-OPER-HSP-AMT            PIC 9(08)V99.
055300         10  PPS-PC-VARIABLES.
055400             15  PPS-OPER-DSH                PIC 9(01)V9(04).
055500             15  PPS-CAPI-DSH                PIC 9(01)V9(04).
055600             15  PPS-CAPI-HSP-PCT            PIC 9(01)V9(02).
055700             15  PPS-CAPI-FSP-PCT            PIC 9(01)V9(04).
055800             15  PPS-ARITH-ALOS              PIC 9(02)V9(01).
055900             15  PPS-PR-WAGE-INDEX           PIC 9(02)V9(04).
056000             15  PPS-TRANSFER-ADJ            PIC 9(01)V9(04).
056100             15  PPS-PC-HMO-FLAG             PIC X(01).
056200             15  PPS-PC-COT-FLAG             PIC X(01).
056300             15  PPS-OPER-HSP-PART2          PIC 9(07)V9(02).
056400             15  PPS-BUNDLE-ADJUST-AMT       PIC S9(07)V99.
056500         10  PPS-ADDITIONAL-PAY-INFO-DATA.
056600             15  PPS-UNCOMP-CARE-AMOUNT       PIC S9(07)V9(2).
056700             15  PPS-BUNDLE-ADJUST-AMT        PIC S9(07)V9(2).
056800             15  PPS-VAL-BASED-PURCH-ADJUST-AMT PIC S9(07)V9(2).
056900             15  PPS-READMIS-ADJUST-AMT       PIC S9(07)V9(2).
057000         10  PPS-ADDITIONAL-PAY-INFO-DATA2.
057100             15  PPS-HAC-PROG-REDUC-IND      PIC X.
057200             15  PPS-EHR-PROG-REDUC-IND      PIC X.
057300             15  PPS-EHR-ADJUST-AMT          PIC S9(07)V9(02).
057400             15  PPS-STNDRD-VALUE            PIC S9(07)V9(02).
057500             15  PPS-FLX6-PAYMENT            PIC S9(07)V9(02).
057600             15  PPS-FLX7-PAYMENT            PIC S9(07)V9(02).
057700         10  PPS-FILLER                      PIC X(0897).
057800*************************************************************
057900
058000
058100 01  PROV-RECORD-FROM-USER.
058200     05  PROV-REC1                  PIC X(80).
058300     05  PROV-REC2                  PIC X(80).
058400     05  PROV-REC3                  PIC X(150).
058500
058600 01  MSAX-TABLE-FROM-USER.
058700     05  FILLER                     PIC X(32000).
058800     05  FILLER                     PIC X(30000).
058900     05  FILLER                     PIC X(30000).
059000
059100 01  CBSA-TABLE-FROM-USER.
059200     05  FILLER                     PIC X(32000).
059300     05  FILLER                     PIC X(30000).
059400     05  FILLER                     PIC X(30000).
059500
059600*******************************************************
059700*    HOLD VARIABLES POPULATED IN PPCAL___***          *
059800*******************************************************
059900 COPY PPHOLDAR.
060000
060100******************************************************************
060200 PROCEDURE DIVISION  USING BILL-NEW-DATA
060300                           PPS-DATA
060400                           PRICER-OPT-VERS-SW
060500                           PPS-ADDITIONAL-VARIABLES
060600                           PPHOLDAR-HOLD-AREA
060700                           PROV-RECORD-FROM-USER
060800                           MSAX-TABLE-FROM-USER
060900                           CBSA-TABLE-FROM-USER.
061000
061100******************************************************************
061200*    PROCESSING:
061300*        A. I/O THE PRICER FILES
061400*        B. THIS MODULE WILL LOAD ALL TABLES THE FIRST TIME THIS
061500*           SUBROUTINE IS CALLED.
061600*        C. ALL FILES WILL BE PASSED TO THE PPDRV___ PROGRAM.
061700******************************************************************
061800
061900     MOVE ALL '0' TO PPS-DATA.
062000
062100******************************************************************
062200
062300 0010-LOAD-TABLES.
062400     IF  PRICER-OPTION-SW  = 'A'
062500         PERFORM 1900-OPTION-SW-A THRU 1900-EXIT
062600     ELSE
062700     IF  PRICER-OPTION-SW  = 'P'
062800         PERFORM 2000-OPTION-SW-P THRU 2000-EXIT
062900     ELSE
063000         PERFORM 2100-OPTION-SW THRU 2100-EXIT.
063100
063200******************************************************************
063300***  GET THE PROVIDER RECORD TO BE PASSED TO PPDRV___
063400
063500 0020-GET-PROVIDER.
063600
063700     IF PROV-RECORD-PASSED OR ALL-TABLES-PASSED
063800        PERFORM 1350-N-CHECK-MSA
063900        MOVE 00 TO PPS-RTC
064000     ELSE
064100        PERFORM 1200-GET-THIS-PROVIDER THRU 1200-EXIT.
064200
064300***     RTC = 51  --  PROVIDER NOT FOUND
064400     IF PPS-RTC = 51
064500          MOVE ALL '0' TO  PPS-ADDITIONAL-VARIABLES
064600          GOBACK.
064700
064800******************************************************************
064900
065000     CALL  PPDRV171 USING BILL-NEW-DATA
065100                          PPS-DATA
065200                          PRICER-OPT-VERS-SW
065300                          PPS-ADDITIONAL-VARIABLES
065400                          PROV-NEW-HOLD
065500                          MSAX-WI-TABLE
065600                          CBSA-WI-TABLE
065700                          PPHOLDAR-HOLD-AREA.
065800      GOBACK.
065900******************************************************************
066000
066100 1200-GET-THIS-PROVIDER.
066200***************************************************************
066300*    ON A PROVIDER BREAK:                                     *
066400*        FIND THE NEW PROVIDER SPECIFIC DATA ELEMENTS         *
066500*    NOTE: IF BILLS ARE BATCHED BY PROVIDER, FEWER TABLE      *
066600*             SEARCHES WILL BE NECESSARY.                     *
066700***************************************************************
066800     IF  B-N-PROVIDER-NO NOT = P-NEW-PROVIDER-NO
066900         SET PX2 TO 1
067000         SEARCH PROV-ENTRIES VARYING PX2
067100             AT END
067200                 MOVE 51 TO PPS-RTC
067300                 GO TO 1200-EXIT
067400             WHEN B-N-PROVIDER-NO = PROV-NO (PX2)
067500                 MOVE 00 TO PPS-RTC.
067600
067700     MOVE PROV-DATA1 (PX2) TO PROV-NEWREC-HOLD1.
067800     SET PD2 TO PX2.
067900     SET PD3 TO PX2.
068000     MOVE PROV-DATA2 (PD2) TO PROV-NEWREC-HOLD2.
068100     MOVE PROV-DATA3 (PD3) TO PROV-NEWREC-HOLD3.
068200
068300     PERFORM 1350-N-CHECK-MSA.
068400
068500     PERFORM 1300-GET-CURR-PROV THRU 1300-EXIT VARYING PX3
068600         FROM PX2 BY 1 UNTIL PROV-NO (PX3) NOT =
068700         B-N-PROVIDER-NO OR PROV-NO (PX3) = '999999'.
068800
068900 1200-EXIT.  EXIT.
069000
069100 1300-GET-CURR-PROV.
069200     IF  B-N-DISCHARGE-DATE NOT < PROV-EFF-DATE (PX3)
069300         MOVE PROV-DATA1 (PX3) TO PROV-NEWREC-HOLD1
069400         SET PD2 TO PX3
069500         SET PD3 TO PX3
069600         MOVE PROV-DATA2 (PD2) TO PROV-NEWREC-HOLD2
069700         MOVE PROV-DATA3 (PD3) TO PROV-NEWREC-HOLD3
069800         PERFORM 1350-N-CHECK-MSA.
069900
070000 1300-EXIT.  EXIT.
070100
070200 1350-N-CHECK-MSA.
070300
070400     IF P-NEW-EFF-DATE < 20041001
070500        IF (P-NEW-WAGE-INDEX-LOC-MSA = '    ' OR
070600            P-NEW-WAGE-INDEX-LOC-MSA = '0000')
070700            MOVE P-NEW-GEO-LOC-MSA9 TO P-NEW-WAGE-INDEX-LOC-MSA.
070800     IF P-NEW-EFF-DATE < 20041001
070900        IF (P-NEW-STAND-AMT-LOC-MSA = '    ' OR
071000            P-NEW-STAND-AMT-LOC-MSA = '0000')
071100            MOVE P-NEW-GEO-LOC-MSA9 TO P-NEW-STAND-AMT-LOC-MSA.
071200
071300     IF P-NEW-EFF-DATE > 20040930
071400        IF (P-NEW-CBSA-RECLASS-LOC = '     ' OR
071500            P-NEW-CBSA-RECLASS-LOC = '00000')
071600            MOVE P-NEW-CBSA-GEO-LOC9 TO P-NEW-CBSA-RECLASS-LOC.
071700     IF P-NEW-EFF-DATE > 20040930
071800        IF (P-NEW-CBSA-STAND-AMT-LOC = '     ' OR
071900            P-NEW-CBSA-STAND-AMT-LOC = '00000')
072000            MOVE P-NEW-CBSA-GEO-LOC9 TO P-NEW-CBSA-STAND-AMT-LOC.
072100
072200 1350-N-EXIT.  EXIT.
072300
072400******************************************************************
072500 1500-LOAD-ALL-TABLES.
072600***************************************************************
072700*    THE FIRST TIME CALLED:                                   *
072800*        LOAD ALL TABLES SUPPLIED BY CMS                      *
072900*        LOAD THE PROVIDER SPECIFIC TABLE SUPPLIED BY         *
073000*             THE INTERMEDIARY.                               *
073100***************************************************************
073200     MOVE HIGH-VALUES TO MSAX-WI-TABLE.
073300     MOVE HIGH-VALUES TO CBSA-WI-TABLE.
073400     MOVE ALL '9' TO PROV-NEW-HOLD.
073500     MOVE ALL '9' TO PROV-TABLE.
073600     MOVE ALL '9' TO PROV-DATA-2.
073700     MOVE ALL '9' TO PROV-DATA-3.
073800     OPEN  INPUT  PROV-FILE.
073900     MOVE 0 TO EOF-SW.
074000     SET PX1 TO EOF-SW.
074100
074200     PERFORM 1600-READ-PROV-FILE THRU 1600-EXIT
074300                           UNTIL EOF-SW = 1.
074400
074500     CLOSE        PROV-FILE.
074600     PERFORM 1700-LOAD-MSAX-FILE THRU 1700-EXIT.
074700     PERFORM 1750-LOAD-CBSA-FILE THRU 1750-EXIT.
074800
074900 1500-EXIT.  EXIT.
075000
075100 1600-READ-PROV-FILE.
075200     READ PROV-FILE
075300         AT END
075400             SET PX1 UP BY 1
075500             MOVE ALL '9' TO PROV-DATA1 (PX1)
075600             SET PD2 TO PX1
075700             SET PD3 TO PX1
075800             MOVE ALL '9' TO PROV-DATA2 (PD2)
075900             MOVE ALL '9' TO PROV-DATA3 (PD3)
076000             MOVE '999999' TO P-NEW-PROVIDER-NO
076100             MOVE 1 TO EOF-SW.
076200
076300     IF  EOF-SW = 0
076400         SET PX1 UP BY 1
076500         MOVE PROV-PART1 TO PROV-DATA1 (PX1)
076600         SET PD2 TO PX1
076700         SET PD3 TO PX1
076800         MOVE PROV-PART2 TO PROV-DATA2 (PD2)
076900         MOVE PROV-PART3 TO PROV-DATA3 (PD3).
077000
077100 1600-EXIT.  EXIT.
077200
077300 1700-LOAD-MSAX-FILE.
077400     OPEN  INPUT  MSAX-FILE.
077500     MOVE 0 TO EOF-SW.
077600     SET MU3 TO EOF-SW.
077700
077800     PERFORM 1800-READ-MSAX-FILE THRU 1800-EXIT
077900                      UNTIL EOF-SW = 1.
078000     CLOSE        MSAX-FILE.
078100
078200 1700-EXIT.  EXIT.
078300
078400 1750-LOAD-CBSA-FILE.
078500     OPEN  INPUT  F-CBSA-FILE.
078600     MOVE 0 TO EOF-SW.
078700     SET MA3 TO EOF-SW.
078800
078900     PERFORM 1850-READ-CBSA-FILE THRU 1850-EXIT
079000                      UNTIL EOF-SW = 1.
079100     CLOSE  F-CBSA-FILE.
079200
079300 1750-EXIT.  EXIT.
079400
079500 1800-READ-MSAX-FILE.
079600     READ MSAX-FILE
079700         AT END
079800             MOVE 1 TO EOF-SW.
079900
080000     IF  EOF-SW = 0
080100             IF  XE-DATE > '19860930' OR
080200                (M-STATE = '98' OR '99')
080300                SET MU3 UP BY 1
080400                MOVE X-MSA-X      TO M-MSAX-MSA        (MU3)
080500                MOVE X-SIZE       TO M-MSAX-SIZE       (MU3)
080600                MOVE XE-DATE      TO M-MSAX-EFF-DATE   (MU3)
080700                MOVE X-WAGE-INDX1 TO M-MSAX-WAGE-INDX1 (MU3)
080800                MOVE X-WAGE-INDX2 TO M-MSAX-WAGE-INDX2 (MU3).
080900
081000 1800-EXIT.  EXIT.
081100
081200 1850-READ-CBSA-FILE.
081300     READ F-CBSA-FILE
081400         AT END
081500             MOVE 1 TO EOF-SW.
081600
081700     IF  EOF-SW = 0
081800             IF  F-CBSA-EFF-DATE > '20030930' OR
081900                (F-CBSA-STATE = '98' OR '99')
082000                SET MA3 UP BY 1
082100            MOVE F-CBSA            TO T-CBSA            (MA3)
082200            MOVE F-CBSA-SIZE       TO T-CBSA-SIZE       (MA3)
082300            MOVE F-CBSA-EFF-DATE   TO T-CBSA-EFF-DATE   (MA3)
082400            MOVE F-CBSA-WAGE-INDX1 TO T-CBSA-WAGE-INDX1 (MA3)
082500            MOVE F-CBSA-WAGE-INDX2 TO T-CBSA-WAGE-INDX2 (MA3).
082600
082700 1850-EXIT.  EXIT.
082800
082900 1900-OPTION-SW-A.
083000     MOVE ALL '9'               TO PROV-NEW-HOLD.
083100     MOVE PROV-RECORD-FROM-USER TO PROV-NEW-HOLD.
083200     IF  TABLES-LOADED-SW = 0
083300         MOVE HIGH-VALUES           TO MSAX-WI-TABLE
083400         MOVE MSAX-TABLE-FROM-USER  TO MSAX-WI-TABLE
083500         MOVE HIGH-VALUES           TO CBSA-WI-TABLE
083600         MOVE CBSA-TABLE-FROM-USER  TO CBSA-WI-TABLE
083700         MOVE 1 TO TABLES-LOADED-SW.
083800
083900 1900-EXIT.  EXIT.
084000
084100 2000-OPTION-SW-P.
084200     MOVE ALL '9'               TO PROV-NEW-HOLD.
084300     MOVE PROV-RECORD-FROM-USER TO PROV-NEW-HOLD.
084400     IF  TABLES-LOADED-SW = 0
084500         MOVE HIGH-VALUES       TO MSAX-WI-TABLE
084600         MOVE HIGH-VALUES       TO CBSA-WI-TABLE
084700         PERFORM 1700-LOAD-MSAX-FILE THRU 1700-EXIT
084800         PERFORM 1750-LOAD-CBSA-FILE THRU 1750-EXIT
084900         MOVE 1 TO TABLES-LOADED-SW.
085000
085100 2000-EXIT.  EXIT.
085200
085300 2100-OPTION-SW.
085400     IF  TABLES-LOADED-SW = 0
085500         PERFORM 1500-LOAD-ALL-TABLES THRU 1500-EXIT
085600         MOVE 1 TO TABLES-LOADED-SW.
085700
085800 2100-EXIT.  EXIT.
085900
086000***************************************************************
086100******       L A S T   S O U R C E   S T A T E M E N T    *****
